Perl (71) - Navazování proměnných

Perl Funkce tie umožňuje přetěžovat takové operace jako čtení z proměnné nebo zápis. Obyčejné přiřazení tak může vykonat daleko více než jen přiřazení.

11.7.2008 09:00 | Jiří Václavík | přečteno 14406×

Mechanizmus tie umožňuje při běžné manipulaci s proměnnými provádět definované akce. Sami si tak obsluhujeme takové rutiny jako je ukládání dat do proměnné nebo čtení jejich obsahu.

V praxi to funguje tak, že si pomocí tie svážeme libovolnou proměnnou s nějakým námi definovaným objektem a při manipulaci s touto navázanou proměnnou se místo obvyklé akce volá určená metoda z objektu. Proměnná tak již nebude řízena Perlem, ale námi napsanou třídou.

Obecná syntaxe příkazu vypadá následovně.

tie $proměnná, "Třída" [, @seznam];

Návratovou hodnotou příkazu tie je již konkrétní objekt, se kterým je proměnná svázána. @seznam je seznam hodnot, které budou předány konstruktoru.

Proměnná je skalár, pole, hash nebo ovladače souboru, který chceme svázat s třídou Třída.

Provádění příkazu tie zahrnuje několik důležitých kroků. Nejprve si Perl určí datový typ předávané proměnné. Dále je volána metoda objektu - pro skaláry je to metoda TIESCALAR, pro pole TIEARRAY, pro hashe TIEHASH a pro ovladače TIEHANDLE. Tyto čtyři metody jsou v podstatě konstruktory, které vrací nyní už konkrétní objekt. Právě tento objekt je s proměnnou svázán.

Nyní je pří každé akci s danou proměnnou (uložení hodnoty do proměnné apod.) vyvolána určitá metoda třídy. Která metoda se vyvolá záleží na typu akce (jiná metoda se vyvolá při ukládání a jiná při čtení).

Navázání proměnné můžeme zrušit příkazem untie. Jakmile zavoláme untie, provede se metoda UNTIE. Nakonec po zrušení všech odkazů na proměnnou (při zániku proměnné) se volá destruktor - metoda DESTROY.

Nyní si rozebereme jednotlivé metody pro všechny dostupné datové typy.

Navazování skalárů

Jak již víme, konstruktorem navázaného objektu pro skaláry je metoda TIESCALAR.

Pokud se nyní pokusíme do navázané proměnné uložit hodnotu, vyvolá se další speciální metoda STORE. Ona ukládaná hodnota se však ve skutečnosti nikam neuloží, ale dostaneme ji jako argument metody STORE.

Podobně, když obsah proměnné čteme, vyvolá se metoda FETCH.

Užití navazování

Zkusme si nyní představit, jak bychom užili mechanizmus tie v praxi. tie bychom teoreticky mohli použít například jako řízení regulačních tyčí jaderného reaktoru. Při zápisu do proměnné by se hodnota poslala do centra, které řídí regulační tyče a ty by se automaticky o tuto hodnotu posunuli. Naopak při čtení proměnné bychom si požádali o aktuální stav.

Další analogií by mohlo být měření stavu počasí - typicky například barometr. Při čtení bychom dostávali informaci o aktuální hodnotě tlaku například v nějaké nádobě. Zápis do proměnné by naopak sloužil pro jeho regulaci, případně bychom ho mohli ignorovat.

Příklad

Barometr ani teplotní senzory však většina lidí k počítači připojeny nemá. Napíšeme si tedy o něco jednodušší program. Při zápisu do proměnné budeme chtít přepsat získanou hodnotou určený soubor. Naopak při čtení z tohoto souboru data získáme. Toho by se dalo teoreticky využít například pro uchovávání obsahu proměnných mezi několika instancemi programu.

Prvním úkolem tedy je napsat modul StoreToFile, jež bude manipulaci s proměnnými řídit. Náš modul bude obsahovat tři metody. První z nich bude konstruktor TIESCALAR. TIESCALAR bude vyžadovat název souboru jako argument. Pokud ho neuvedeme, implicitně se použije soubor tiefile. Název souboru vzápětí zkonvertujeme na objekt.

package StoreToFile;

sub TIESCALAR {
    my($pkg, $soubor) = @_;
    $soubor = "tiefile" unless $soubor;
    bless \$soubor, $pkg;
    return \$soubor;
}

Dále definujeme metodu STORE. Ta bude volána vždy při zápisu do proměnné. Získaná hodnota (hodnotu získáme jako argument metody) bude zapsána do souboru, jehož jméno uchovává objekt.

sub STORE {
    my($r_fh, $hodnota) = @_;
    open FILE, ">$$r_fh" or die;
    print FILE $hodnota;
    close FILE;
}

A nakonec ještě napíšeme metodu FETCH, jež bude vracet obsah souboru ve formě řetězce.

sub FETCH {
    my($r_fh) = @_;
    open FILE, "$$r_fh" or die;
    my $data = <FILE>;
    close FILE;
    return $data;
}

To je téměř vše. Definice třídy je již hotova. Jak se můžeme přesvědčit, jde o normální třídu, kterou bychom mohli běžným způsobem používat. Nápadné jsou pouze názvy metod. Nicméně je třeba připomenout, že tyto metody se chovají speciálně pouze pokud instanci třídy svážeme pomocí tie.

Nyní třídu použijeme tak, že ji svážeme s proměnnou příkazem tie. Zároveň konstruktoru předáme název souboru parametr.

tie $a, "StoreToFile", "soubor";

A následně můžeme testovat. Uložíme do proměnné $a jakoukoliv hodnotu.

$a = "Obsah svázané proměnné";

Můžeme se přesvědčit, že vznikl soubor soubor, který obsahuje text přiřazený proměnné $a. To je důkazem skutečnosti, že se vykonala metoda STORE svázaného objektu.

Poznámka - Předcházející přiřazení do proměnné $a bychom mohli přepsat jako volání metody nad objektem. Tento objekt získáme pomocí příkazu tied, jež právě navázaný objekt vrací (a nebo jako návratovou hodnotu příkazu tie). Následující dva příkazy tedy dělají to samé.

$a = "Obsah svázané proměnné";
(tied $a)->STORE("Obsah svázané proměnné");

A dále zkusíme proměnnou přečíst. Nyní se vyvolá metoda FETCH, která přečte daný soubor a získaná data vrátí.

print $a;

Přetížení pouze vybraných operací pomocí modulu Tie::Scalar

Pokud se už rozhodneme přetížit operace se skalárními proměnnými, musíme přetížit všechny. To je zbytečné v případech, kdy od jedné nebo více metod chceme implicitní chování.

Přímo se tedy nabízí vytvořit nějakou třídu s metodami, jejichž chování bude stejné s tím, jak manipuluje s proměnnými Perl. Taková třída již existuje, jmenuje se Tie::StdScalar a patří do standartní výbavy modulů. Pokud tedy necháme námi napsanou třídu dědit od Tie::StdScalar, můžeme přetížit jen požadované metody.

Ukážeme si to na krátkém příkladu. Napíšeme třídu, která zaokrouhlí výstupní hodnotu na dvě desetinná místa.

Importujeme tedy Tie::Scalar, ve kterém je i definice Tie::StdScalar. A jediné, co dále potřebujeme je nastavení předka naší třídy.

package StoreToFile;
use Tie::Scalar;
@ISA = ("Tie::StdScalar");

sub FETCH {
    return sprintf("%.2f", ${$_[0]});
}
Online verze článku: http://www.linuxsoft.cz/article.php?id_article=1556