Perl má k dispozici několik modulů, které poskytují prostředky pro usnadnění často používaných operací v CGI skriptech. Nejznámějším z této kategorie je modul CGI.27.7.2009 01:00 | Jiří Václavík | přečteno 12880×
Perl má k dispozici několik modulů, které poskytují prostředky pro usnadnění často používaných operací v CGI skriptech. Nejznámějším z této kategorie je modul CGI.
27.7.2009 01:00 | Jiří Václavík | přečteno 12880×
CGI modul v mnohém zjednodušuje programátorovi práci. Zejména pomáhá se zpracováváním parametrů, zpřístupňuje proměnné prostředí jako metody, usnadňuje práci s cookies. Dále možňuje zapisovat HTML elementy pomocí volání funkcí. Tyto funkce vracejí kód formátovaný do jazyka HTML, který pak můžeme například tisknout funkcí print.
Modul CGI poskytuje jak funkcionální tak objektově-orientované rozhraní. Záleží na nás, co je nám bližší. Abychom se s modulem CGI seznámili blíže, přepíšeme si příklad z 82. dílu s použitím obou těchto stylů zvlášť.
U funkcionálního použití modulu voláme ke generování HTML, získávání parametrů, práci s cookies apod. k tomu určené funkce. Tyto funkce potřebujeme importovat do našeho jmenného prostoru.
Modul CGI obsahuje několik kategorií těchto funkcí. Jsou popsány v následující tabulce.
| Skupina | Význam |
| :all | importují se všechny funkce, které modul CGI obsahuje |
| :standard | importuje standardní vlastnosti, :html2, :html3, :html4, :form a :cgi |
| :cgi | import všech obsluhujících metod jako například param, cookie |
| :html, :html2, :html3, :html4, :form | import příslušných HTML elementů |
Toto sice nejsou veškeré dostupné třídy funkcí, nicméně ty ostatní jsou pro naše účely nevýznamné. Pro toho, kdo se chce možnostmi webového programování zabývat více do hloubky, může být v tomto směru poučné nahlédnout do zdrojového kódu modulu CGI, kde najdeme všechny třídy i se všemi funkcemi, které do nich patří.
Ve valné většině případů si vystačíme s importem kategorie :standard.
Přistupme nyní již ke konkrétní ukázce použití funkcionálního rozhraní modulu CGI.
#!/usr/bin/perl -T
use strict;
use CGI qw(:standard);
my $now = localtime;
print header("text/html");
print start_html("Hello World");
print h2("Hello World");
print $now;
print end_html;
HTML prohlížeč zobrazí to samé, co zobrazil náš první příklad v minulém dílu. Kód je však o poznání kratší a o něco jednodušší. Pro lepší srovnání uveďme, jak vypadal náš původní kód.
my $now = localtime;
print << "HTML";
<!DOCTYPE HTML PUBLIC "-//W3C//DTD HTML 4.01 Transitional//EN" "http://www.w3.org/TR/html4/loose.dtd">
<HTML>
<HEAD>
<TITLE>Hello World</TITLE>
</HEAD>
<BODY>
<H2>Hello world</H2>
$now
</BODY>
</HTML>
HTML
Funkce header vrací povinnou hlavičku, ve které je MIME typ dokumentu. Další funkce start_html a end_html vytvářejí hlavu a patu HTML dokumentu. Importují příslušný DTD soubor a nastavují titulek stránky. Mezi nimi je tělo dokumentu.
Použití této části modulu je o něco náročnější na psaní kódu. Musíme totiž vytvořit objekt a následně nad ním volat metody namísto volání obyčejných funkcí, jako je tomu u funkcionálního programování. Avšak na druhou stranu nemusíme vybírat kategorie funkcí, které chceme importovat.
Ukázka kódu, která dělá pro srovnání opět totéž, je zde.
#!/usr/bin/perl -T
use strict;
use CGI;
my $now = localtime;
my $cgi = new CGI;
print $cgi->header("text/html");
print $cgi->start_html("Hello World");
print $cgi->h2("Hello World");
print $now;
print $cgi->end_html;
Zdlouhavost získávání parametrů ze vstupu přímo vybízela k vytvoření funkce, která by tuto činnost zjednodušila. Jednou z nejdůležitějších úloh modulu CGI je právě obsluha vstupu dat.
Funkce param dělá dvě věci. Tou první je, že, je-li volána bez argumentu, vrací seznam parametrů vstupu bez hodnot. Tou druhou je vracení samotných hodnot. Abychom získali hodnotu, je třeba funkci předat navíc i název parametru. Hodnota může být pro určité typy fomulářů i seznam - potom je vracen seznam těchto hodnot.
Následující CGI skript zobrazí všechny parametry i s hodnotami, nehledě na typ vstupu. Funkce param řeší i parametry s hodnotou v seznamovém kontextu, takže je třeba ošetřit zobrazení seznamu.
#!/usr/bin/perl
use strict;
use CGI qw(:standard);
print "Content-type: text/plain\n\n";
for (param){
print "$_: ", join(", ", param($_)), "\n";
}
Voláním param s více parametry má za následek přidání parametru. První parametr se stane klíčem, další parametry jsou jeho hodnotami. Funkce append vybranému parametru přidá hodnotu. Funkce Delete (velké D proto, protože delete již existuje v základní distribuci Perlu) (resp. Delete_all) maže příslušné parametry.
Pro hledání chyb lze využít funkci Dump, která vrací seznam parametrů s hodnotami formátovaný v HTML.
Potřebujeme-li všechny přijaté parametry importovat do vybraného balíku, použijeme funkci import_names. Její užití vypadá následovně.
import_names("P");
print $P::jmenoparametru;
Funkce nebo metody (dále pouze funkce) mohou obvykle přijímat žádný, jeden nebo více argumentů. Tyto argumenty jsou přijímany většinou ve formě hashe. Hashové klíče začínají vždy pomlčkou. Například funkci header můžeme volat tímto způsobem.
header(-type => "text/html", -charset=>"utf-8");
Nicméně právě header je možné volat i skalárně, jak je vidět na příkladu výše.
Funkce, kterým není předán žádný parametr vytvoří jednorázový HTML tag ve tvaru <element />. Příkladem takové funkce je hr.
V průběhu seriálu o CGI se však několikkrát setkáme i s funkcemi, které mohou jako argument přijímat složitější datové struktury.
Prvním takovým příkladem mohou být HTML elementy, které přijímají nějaký parametr. Například chceme-li získat pomocí funkce h1 kód <h1 align="center">Hello World</h1>, předáme jako první argument odkaz na hash s příslušnými hodnotami. Volání takové funkce tedy bude vypadat následovně.
h1({-align => "center"}, "Hello World");
Analogické je to i s ostatními funkcemi, které vytváří prvky HTML dokumentu.
Struktura volání funkcí, kterou zatím známe, opomíjí jednu velmi důležitou skutečnost. Neřeší vnořování elementů, což je i v jednoduchých HTML dokumentech nezbytné. Pro tento účel existují speciální funkce ve tvaru start_element a end_element, které generují pouze příslušnou polovinu elementu.
Tyto funkce nejsou importovány ani třídou :standard, ani třídou :all, ani žádnou jinou, takže je musíme zavést zvlášť. Připomeňme, že zde můžeme pro import funkcí start_element a end_element užít žolíkový znak hvězdička. Například pro import funkcí start_h1 a end_h1 dohromady můžeme napsat *h1.
use CGI qw(*h1);
Vnoření pak může vypadat třeba takto.
use CGI qw(*h1 i);
print start_h1, "Hello ", i("Perl"), end_h1;
Poznámka - pokud importujete alespoň jednu z funkcí start_element a end_element, importují se automaticky obě.