V téměř každé aplikaci potřebujeme přiohnout některé standardní widgety tak, aby více odpovídaly našim představám. Toho dosahujeme změnami vlastností, nastavením metod atd. Pokud potřebujeme udělat jistý typ změn často, pak bývá praktické vytvořit si vlastní widget.

Spočívá to v tom, že vytvoříme objekt na základě nějakého již existujícího widgetu. Ten upravíme a případně vytvoříme nové atributy a metody. Vzhledem k tomu, že celá tato úprava je zabalena ve zvláštní třídě, chová se celý modul jako obyčejný widget.

Jako ukázku si vytvoříme jenoduché upravené tlačítko, ze kterého bude hezky vidět, jak widgety tvořit. Naše tlačítko bude obsahovat dva popisky a ty se budou v požadovaných intervalech střídat. Použijeme přitom dva různé přístupy.

Vytvořme tedy třídu MojeBlikajiciTlacitko, která bude upraveným standardním Gtk2::Button (jinými slovy, bude dědit z Gtk2::Button).

package MojeBlikajiciTlacitko;
use base "Gtk2::Button";

Třída MojeBlikajiciTlacitko bude obsahovat dvě metody: konstruktor a metodu pro bliknutí. Napišme nejprve konstruktor.

sub new {
    my $trida = shift;

    #zde vytvoříme vlastní objekt $self

    return $self;
}

Vytvořme tedy nové tlačítko Gtk2::Button a pomocí bless z něj udělejme objekt.

    my $self = bless Gtk2::Button->new, $trida;

Jako první dva parametry konstruktoru budeme očekávat dva popisky. Uložme tyto popisky do speciálních atributů.

    $self->{text0} = $_[0];
    $self->{text1} = $_[1];

Implicitně jeden z popisků nastavíme.

    $self->set_label($self->{text0});

Chceme, aby tlačítko blikalo. Spusťme tedy pomocí časových funkcí pravidelně se opakující změnu popisku. Délka intervalu se bude nastavovat třetím parametrem konstruktoru. Změnu popisku nám zařídí funkce blik, kterou si v zápětí napíšeme.

    Glib::Timeout->add($_[2], \&blik, $self);

Metoda blik pouze nastaví popisek na ten, který právě není aktivní.

sub blik {
    my $self = shift;
       $self->set_label($self->get_label eq $self->{text0} ? $self->{text1} : $self->{text0});
       return 1;
}

Právě jsme vytvořili widget MojeBlikajiciTlacitko, které nyní již můžeme vesele používat. Následuje ukázkový program obsahující tento widget.

package main;

use Gtk2 -init;

my $okno = Gtk2::Window->new;
$okno->set_border_width(5);
$okno->signal_connect(delete_event => sub{Gtk2->main_quit;});

my $tlacitko = MojeBlikajiciTlacitko->new("Klikni", "sem!", 500);
$okno->add($tlacitko);

$okno->show_all;
Gtk2->main;

Jiný způsob přetěžování widgetů, emitace vlastních signálů

Existuje ještě metoda, jak přetěžovat widgety. Přimějeme naši třídu, aby se chovala jako Glib::Object. Bohužel to není tak jednoduché, aby stačilo pouze voláním bless prohlásit třídu za objekt Glib::Object, protože se musíme starat o věci jako jsou signály. Stručně se podívejme, jak se to tedy dělá.

Vytvořme opět widget MojeBlikajiciTlacitko.

package MojeBlikajiciTlacitko;

Pomocí Glib::Object::Subclass nastavíme všechny atributy a signály, které budeme chtít dále používat. Provádíme v zásadě podobnou činnost jako pragma base. Předáme tedy následující datové struktury příkazu use. Vždy musíme předat alespoň první parametr, který určuje, z čeho budeme dědit.

use Glib::Object::Subclass
    Gtk2::Button::,
    signals => {
        text_se_zmenil => {},
        show => \&new_show,
    },
    properties => [
        Glib::ParamSpec->string(
            "text0",
            "Text 0",
            "Prvni z textu, ktery bude problikavat",
            "",
            [qw(readable writable)]
        ),
        Glib::ParamSpec->string(
            "text1",
            "Text 1",
            "Druhy z textu, ktery bude problikavat",
            "",
            [qw(readable writable)]
        ),
        Glib::ParamSpec->uint(
            "interval",
            "Interval",
            "Casovy interval mezi bliknutimi",
            0,100000,
            1000,
            [qw(readable writable)]
        ),
    ]
;

U atributů je důležitý hlavně první parametr - to je jeho název. Pro význam dalších atributů a přidávání jiných datových typů než je číslo a řetězec se lze podívat do dokumentace na oddíl o Glib::ParamSpec.

Přetížili jsme metodu show. To proto, že je třeba nastavit úvodní hodnoty, jakmile se widget zobrazí.

sub new_show {
    my $self = shift;
    $self->set_label($self->{text0});
    Glib::Timeout->add($self->{interval}, \&blik, $self);
    $self->signal_chain_from_overridden;
}

Volání signal_chain_from_overridden žádá nadřazenou třídu o zavolání příslušné metody. V seriálu jsme obvykle používali pro podobné účely SUPER::show, avšak zde je třeba s dědičností zacházet trochu jinak.

Protože zde obvykle nevytváříme metodu new (ta je zděděna), je automaticky volána metoda INIT_INSTANCE. Ta se používá pro inicializaci objektů

Samozřejmě potřebujeme i metodu na bliknutí textu. Zde pouze přidáme emitaci signálu, který detekuje změnu textu na tlačítku. K tomu použijeme metodu signal_emit.

sub blik {
    my $self = shift;
       $self->set_label($self->get_label eq $self->{text0} ? $self->{text1} : $self->{text0});
       $self->signal_emit("text_se_zmenil");
       1;
}

A použití widgetu je stejné.

package main;

use Gtk2 -init;

my $okno = Gtk2::Window->new;
$okno->set_border_width(5);
$okno->signal_connect(delete_event => sub{Gtk2->main_quit;});

my $tlacitko = MojeBlikajiciTlacitko->new("Klikni", "sem!", 500);
$okno->add($tlacitko);

$okno->show_all;
Gtk2->main;

Vzhledem k tomu, že se vždy po změně textu tlačítka emituje signál, můžeme ho zpracovat. My pouze jako ukázku vypíšeme na standardní výstup hlášku o tom, že signál byl úspěšně zachycen.

$tlacitko->signal_connect(text_se_zmenil => sub {print "Signal o zmene textu na tlacitku zachycen!";});