Prostředí v SCons

Předtím než se podíváme na ovlivňování kompilačních voleb tak se podíváme na práci s prostředími. Když jsem popisoval v prvním díle vlastnosti nástroje SCons tak jsem napsal, že v SCons můžete používat současně více prostředí. V našich příkladech jsme prostředí nepoužívali pohybovali jsme se v implicitním prostředí které SCons automaticky vytváří.

Proto se podíváme na prostředí podrobněji. Prostředí si můžeme nejlépe představit jako dictionary, soubor přiřazení hodnot proměnným. Tyto proměnné se pak používají při překladu a linkování programu. Například proměnná prostředí CC obsahuje jméno kompilátoru, kterým budeme překládat.

Prostředí se vytváří zavolánim funkce Environment. Této funci můžeme předat seznam proměných a hodnot které budou použity pro jeho inicializaci. Pokud žádné nepředáme, tak se nastaví default pro platformu na které kompilujeme. Při vytváření nového prostředí můžeme voláním metody prostředí Clone použít existující prostředí jako základ pro vytvoření nového.

Prostředích si můžeme vytvořit kolik chceme, je však nutné dát pozor aby pokud kompilujeme stejný zdrojový soubor pod více prostředímy byly objektové soubory pojmenovány různě. Jinak by nemohl SCons správně určit který objektový soubor náleží ke kterému prostředí a jak se má dále zpracovávat.

Proměných se standardně nastavuje hodně, ale některé si z nich můžeme pro příklad nechat vypsat.

#SConstruct
env = Environment()
for x in Split("CC CPPFLAGS SHELL CPPPATH JAVAC PLATFORM"):
     try:
        val=env.Dictionary()[x]
        print x,val
     except KeyError:
        print x,"-No value-"

Po spuštění vypíše:

fbsd8:/tmp> scons -Q
CC gcc
CPPFLAGS -No value-
SHELL sh
CPPPATH -No value-
JAVAC javac
PLATFORM posix
scons: `.' is up to date.
fbsd8:/tmp>

Pokud chceme místo gcc clang tak prostředí vytvoříme:

env = Environment(CC='clang')

Proměnou CC můžeme pochopitelně změnit i dodatečně.

env = Environment()
env.Replace(CC='clang')

K proměným prostředí můžeme přistupovat i jinými metodami. Již jsme si ukázali přístup přes Environment.Dictionary() a metodu Replace(). Na hodnotu proměnné CC se ale můžeme dotázat i alternativním způsobem.

env = Environment()
print env.get('CC')
print env['CC']

Mnohem zajímavější než nahrazování hodnot je přidávání retězců ke stávající hodnotě. Vezmeme si kupříkladu proměnnou CPPFLAGS do které se ukládají flagy pro C preprocesor. Nejčastěji to budou přepínače -I pro označení adresář v kterém se budou hledat hlavičkové soubory a -D pro definici hodnot preprocesoru.

Pokud si napíšeme takovýto SConstruct

env = Environment()
env.Append(CPPFLAGS = "-DZERO=0")
env.Append(CPPFLAGS = "-DONE=1")
print env.get('CPPFLAGS')

Tak při jeho spuštění nedostaneme výsledek jaký jsme chtěli.

fbsd8:/tmp> scons -Q
-DZERO=0-DONE=1
scons: `.' is up to date.
fbsd8:/tmp>

Ve výpisu nahoře jsem ukázal že proměnná prostředí CPPFLAGS nemá na začátku přiřazenou žádnou hodnotu. Po provedení příkazu env.Append(CPPFLAGS = "-DZERO=0") se tento string přiřadí do proměnné CPPFLAGS a další příkaz k němu podle očekávání přidá další řetězec. To je sice to co jsme počítači nařídili, ale není to moc optimální protože mezi jednotlivými volbami preprocesoru je potřeba uvádět mezery.

Python je dynamicky typovaný jazyk, proměnná nemá napevno při deklaraci přiřazen typ, ale mění svůj typ podle hodnoty kterou do ní uložíme. Když z CPPFLAGS uděláme typ list, tak dosáhneme kýženého výsledku. Pokud chceme hodnotu vložit na začátek seznamu použijeme namísto Append funkci Prepend. Moc se to nepoužívá protože u většiny přepínačů nezáleží na pořadí.

fbsd8:/tmp> cat Sconstruct
env = Environment()
env.Replace(CPPFLAGS = [])
env.Append(CPPFLAGS = "-DZERO=0")
env.Append(CPPFLAGS = "-DONE=1")
print env.get('CPPFLAGS')
fbsd8:/tmp> scons -Q
['-DZERO=0', '-DONE=1']
scons: `.' is up to date.

Je tu ještě druhá možnost jak docílit stejného efektu a to uzavírat argumenty do hranatých závorek. Tato možnost se mi nelíbí protože toho musíte zbytečně psát více a nevypadá to tak pěkně.

fbsd8:/tmp> cat Sconstruct
env = Environment()
env.Append(CPPFLAGS = ["-DZERO=0"])
env.Append(CPPFLAGS = ["-DONE=1"])
print env.get('CPPFLAGS')
fbsd8:/tmp> scons -Q
['-DZERO=0', '-DONE=1']
scons: `.' is up to date.

Další z možností jak přiřazovat hodnotu proměnné je AppendUnique, pokud máme složitější konfiguraci tak je to velmi užitečná volba. Pokud námi zadaná hodnota již existuje v seznamu hodnot proměnné tak se přiřazení ignoruje a hodnota zůstane v seznam jen jednou.

fbsd8:/tmp> cat Sconstruct
env = Environment()
env.Replace(CPPFLAGS = [])
env.Append(CPPFLAGS = "-DZERO=0")
env.Append(CPPFLAGS = "-DONE=1")
env.Append(CPPFLAGS = "-DONE=1")
env.AppendUnique(CPPFLAGS = "-DZERO=0")
print env.get('CPPFLAGS')
fbsd8:/tmp> scons -Q
['-DZERO=0', '-DONE=1', '-DONE=1']
scons: `.' is up to date.

Všimněte si že -DZERO je ve výsledku jednou -DONE dvakrát.

Poslední, ačkoliv ne moc často používanou, vlastností kterou vám dnes ukáži je nahrazování proměnných hodnotami v textovém řetězci. Jedná se o velmi jednoduché formátování výstupu a podobnou vlastnost najdeme v mnoha skriptovacích jazycích. Toto formátování je rekurzivní, takže můžeme jako hodnotu proměnné použít odkaz na jinou proměnnou. Lépe to pochopíme na příkladu.

fbsd8:/tmp> cat Sconstruct
env = Environment()
env.Replace(CPPFLAGS = [])
env.Replace(ZERO = 0)
env.Append(CPPFLAGS = "-DZERO=$ZERO")
env.Append(CPPFLAGS = "-DONE=1")
print env.subst('CPPFLAGS are $CPPFLAGS')
print env.get('CPPFLAGS')
fbsd8:/tmp> scons -Q
CPPFLAGS are -DZERO=0 -DONE=1
['-DZERO=$ZERO', '-DONE=1']
scons: `.' is up to date.

Co jsme se naučili

Po dnešku by jste už měli umět pracovat v nástroji SCons s prostředími. Sliboval jsem, že se dnes naučíte ovlivňovat volby kompilace, což je možné pokud nastavíme proměnné prostředí na námi požadované hodnoty. Kupříkladu proměnná CC označuje překladač, CPPFLAGS určuje parametry preprocesoru atd.

Na seznam důležitých proměnných a na to jak improtovat a exportovat proměnné z a do prostředí operačního systému se podíváme příště.