ARCHIV

Perl (105) - Testování programových jednotek

Při komplexnějších úlohách bývá zvykem testovat funkčnost jednotlivých komponent (například podprogramů). Předvedeme si jeden z nástrojů, jak na to.

15.3.2010 12:00 | Jiří Václavík | Články autora | přečteno 10818×

Testování programových jednotek (unit testing) znamená ověřování správného chodu jednotlivých úseků programu. Je to tedy metoda hledání chyb.

Testovat lze libovolný úsek programu, u kterého to má smysl. Často se například testují podprogramy nebo metody.

Záměrem je právě testovaný úsek maximálně izolovat od zbytku programu. Měl by být na okolí co možná nejnezávislejší.

Unit testing a Perl

Podívejme se na úvod na nejjednodušší možný test.

Příklad testu

Zde je zdrojový kód.

print "1..2\n";
print 1 == 1 ? "ok 1\n" : "not ok 1\n";
print 1 == 2 ? "ok 2\n" : "not ok 2\n";

Prvním řádkem avizujeme, že uděláme dva testy, které na dalších dvou řádcích následují. Tento zápis je obvyklou konvencí. Spuštěním takového programu získáme následující výstup.

1..2
ok 1
not ok 2

První test dopadl podle očekávání úspěšně, druhý nikoliv.

Testy pomocí modulu Test::More

V Perlu se dá pro usnadnění testování použít řada modulů. Podíváme se zde speciálně na modul Test::More. Naučíme se používat některé jeho funkce.

Modul Test::More zavádíme obvykle s parametrem, kterým říkáme, kolik testů budeme provádět. Zde je příklad.

use Test::More tests => 10;

Pokud zadáme jiný počet, než nakonec provedeme, program si na konci postěžuje. Modul lze také zavádět s parametrem no_plan. To znamená, že počet testů neznáme. V takovém případě se budou normálně provádět testy, na které program narazí, ale ztratíme tím některé možností.

use Test::More "no_plan";

Lepší než no_plan však často je lepší dodat počet testů na konci. Pak má program následující schéma.

use Test::More tests => 2;

# testy

done_testing(pocet_testu);

Náš první příklad bychom mohli přehledněji přepsat pomocí exportované funkce ok do následující podoby.

use Test::More tests => 2;
ok(1 == 1);
ok(1 == 2);

Spustíme-li tento program, provede se totéž jako prve, ale navíc zde přibyde nějaký závěrečný komentář o tom, kolik testů našlo chyby.

1..2
ok 1
not ok 2
#   Failed test at more.pl line 3.
# Looks like you failed 1 test of 2.

Příklad testování modulu

Vybereme si nějaký modul a ukážeme pomocí něj několik věcí, které můžeme testovat. Zvolíme například modul Math::Complex, který zavádí objekty typu komplexní číslo a provádí s nimi základní operace.

Nejprve uveďme, že funkci ok lze předat jako argument komentář, který se má objevit na výstupu.

Nyní zkusme udělat několik jednoduchých testů.

use Test::More tests=>4;
use Math::Complex;

$z1 = Math::Complex->make(1, 2);
$z2 = Math::Complex->make(3, 4);
$z3 = Math::Complex->make(4, 6);
$z4 = Math::Complex->make(-8, 10);

ok(defined $z1, "metoda make chodi. Vytvoreno: '$z1'");
ok($z1->isa("Math::Complex"), "metoda make vraci objekt typu Math::Complex");
ok($z1 + $z2 == $z3, "scitani funguje");
ok($z1 * $z2 == $z4, "nasobeni funguje");

Poslední test je ukázkou toho, že když test selže, nutně to neznamená, že je chyba v modulu. V tomto případě je chybně napsaný test a proto selhal. Horší však je, když test neselže, protože je chybně napsaný. Poučením je, že je potřeba vždy dávat pozor.

Porovnávání řetězců - vylepšení funkce ok pomocí is

Funkce is dělá téměř totéž jako ok, ale má jinou strukturu volání a vypisuje více informací. Místo výrazu jí předáme dva argumenty, které se mají porovnat pomocí operátoru eq (to jest skutečná hodnota a očekávaná hodnota). Zatímco ok se může rozhodovat pouze na základě toho, zda je argument pravdivý či nikoliv, funkce is obě porovnávané hodnoty navíc zná.

Upravme tedy testy pomocí is. První dva necháme stejné, protože zde není nic k porovnávání. Avšak na další dva is aplikovat lze.

ok(defined $z1, "metoda make chodi. Vytvoreno: '$z1'");
ok($z1->isa("Math::Complex"), "metoda make vraci objekt typu Math::Complex");
is($z1 + $z2, $z3, "scitani funguje");
is($z1 * $z2, $z4, "nasobeni funguje");

Výstup u čtvrtého testu se změnil. Test selhal a dostáváme navíc informaci o tom, jak se liší obě hodnoty.

1..4
ok 1 - metoda make chodi. Vytvoreno: '1+2i'
ok 2 - metoda make vraci objekt typu Math::Complex
ok 3 - scitani funguje
not ok 4 - nasobeni funguje
#   Failed test 'nasobeni funguje'
#   at komplex2.pl line 12.
#          got: '-5+10i'
#     expected: '-8+10i'
# Looks like you failed 1 test of 4.

Existuje také funkce isnt (pro puntičkáře též varianta s apostrofem isn't), což je negace is. Lze ji užít například následovně k testu neprázdnosti proměnné nebo rozdílnosti dvou proměnných.

isnt($data, "", "mame data");
isnt($a, $b, "a, b se lisi");

Může se hodit též funkce is_deeply, která pomocí porovnává do hloubky datové struktury.

Porovnávání obecně - vylepšení funkce ok pomocí cmp_ok

Podobně funguje funkce cmp_ok. Zde je ale navíc potřeba zadat explicitně operátor, protože máme univerzálnější použití.

cmp_ok($promenna, "==", $ocekavano, "plati rovnost");
cmp_ok($p, "&&", $q, "plati p && q");

Regulární výrazy - vylepšení funkce ok pomocí like

like zjistí, zda předaná hodnota vyhovuje regulárnímu výrazu.

like($cislo, "/^\w+$/", "cislo je korektne zadane");

Lze použít i unlike. Postup je analogický jako v předchozích dvou případech

Testování existence metod

Funkce can_ok otestuje, zda v nějakém modulu existují dané metody. Zde je příklad použití.

can_ok("Modul", qw(metoda1 metoda2 metoda3));

Jiné platformy a přeskakování testů

Pokud některé testy nebudeme moci provést na určitém operačním systému (například nebude obsahovat některé k tomu nezbytné nástroje nebo budeme mít přednastavené jiné hodnoty), můžeme je přeskakovat.

Existuje funkce skip, která přeskočí požadovaný počet testů. Pokud budeme skutečně chtít podmiňovat vykonání testů operačním systémem, pravděpodobně sáhneme po proměnné $^O (alternativně $OSNAME). Její hodnoty jsou například linux, MSWin32, MacOs. Chceme-li rozlišit mezi různými verzemi operačního systému, musíme už využít nějakého externího modulu. To se může stát zejména s různými verzemi Windows, které se mohou výrazně lišit. V takovém případě užijeme například funkci GetOSName v modulu Win32.

SKIP: {
    skip("Nelze testovat na operacnich systemech Windows.", 1) if $^O eq "MSWin32";

    is(...);
}

Subtesty

Jen na okraj poznamenejme, že lze dělat též subtesty.

use Test::More tests => 2;
ok(1);
subtest "subtest" => sub {
      plan tests => 1;
      ok(1);
};

Tento program vyprodukuje následující výstup.

1..2
ok 1
    1..1
    ok 1
ok 2 - subtest

Verze pro tisk