ARCHIV

Perl (106) - Debugování pomocí komentářů

Do komentářů budeme zapisovat příkazy se speciální syntaxí, které nám vypíší ladící informace. Jde o zajímavou alternativu k již známým nástrojům.

24.3.2010 00:00 | Jiří Václavík | Články autora | přečteno 11350×

Komentáře v programu se dají využít i k jiným účelům než jen k popisování toho, co se na kterém řádku děje. Modul Smart::Comments stanovuje pravidla, jak využít komentáře k debugování. Funguje tak, že komentáře mají speciální syntaxi a nejsou jen přeskakovány, nýbrž zvlášť vyhodnoceny.

Nejprve nainstalujeme modul Smart::Comments.

$ cpan Smart::Comments

Aktivace režimu Smart::Comments

Abychom mohli využívat výhod, které modul Smart::Comments skýtá, stačí na začátek programu přidat následující řádek.

use Smart::Comments;

Jakmile program odladíme, budeme pravděpodobně chtít režim vypnout. Zde je nejlepším řešením právě uvedený řádek pouze zakomentovat.

Syntaxe speciálních komentářů

Všechny komentáře, které mají být dále nějakým způsobem vyhodnocovány mají následující tvar.

### příkaz
#### příkaz
##### příkaz

Tyto příkazy mají za následek vypsání požadovaných dat na STDERR.

Křížků na začátku komentáře může být libovolně mnoho, nejméně však tři. Jejich počet dělí příkazy do skupin, které lze podle potřeby aktivovat nebo deaktivovat.

To, které skupiny příkazů budou právě aktivní se určuje podle seznamu parametrů předanému příkazu use. Například tento příkaz ovlivní komentáře tak, že aktivuje pouze příkazy uvedené po třech nebo čtyřech křížcích.

use Smart::Comments "###", "####";

Ostatní (například ty, které začínají pěti křížky) interpretovány nebudou.

Výpis textu

Nejjednodušší úkon, který nám provede Smart::Comments je výpis textu. Jako text se chápe každý příkaz za křížky, který končí třemi tečkami. Zkusme spustit následující kód.

use Smart::Comments;
...
### Pripravuji testovani...
...

Na výstupu na STDERR uvidíme následující.

### Pripravuji testovani...

Na tomto místě je zajímavé se znovu zamyslet nad tím, že komentář skutečně vypisuje data. Takové užití je možná neočekávané, avšak účelné, zejména, jak uvidíme dále, ve spojitosti s dalšími druhy příkazů.

V textu můžeme použít i speciální proměnné.

• <now> - vypíše místo sebe datum a čas
• <here> - vypíše místo sebe jméno souboru a řádek

Zkusme tedy do programu zapracovat následující řádek.

### [<now>] <here> -- Pripravuji testovani...

Ve výstupu bychom měli vidět, že se skutečně proměnné nahradily.

### [Wed Apr 14 02:12:44 2010] "pokus.pl", line 8 -- Pripravuji testovani...

Výpis proměnných

Další věc, kterou lze se Smart::Comments dělat, je výpis aktuální hodnoty nějakého výrazu. Napišme tedy za křížky nějaký výraz. Příklad úseku zdrojového kódu je zde.

use Smart::Comments;
$u = 7;
### 5 * 6
### $u

Tento kód vytiskne po spuštění programu na STDERR následující.

### 5 * 6: 30
### $u: 7

Výrazy s popisky

Příkaz tvaru popisek : výraz tiskne k hodnotě výrazu vlastní popisek. Uveďme příklad.

$pi=$namereny_obvod_kruhu/$namereny_prumer_kruhu;
### Ocekavano: 3.14159265
### Nase aproximace: $pi

Výsledkem po spuštění bude tento výstup.

### Ocekavano: '3.14159265'
### Nase aproximace: '3.14245681'

Kontrola výrazů

Klíčové slovo require (resp. jeho synonyma ensure, insist, assert) vyhodnocuje logický výraz. Očekáváno je, že jeho výsledkem bude pravda. Pokud tomu tak není, bude volána funkce die.

Vložme tedy někam do zdrojového kódu tento řádek.

### require: $rok > 2008

Je-li v proměnné $rok skutečně hodnota větší než 2008, vše je v pořádku a nedostaneme ani žádný výstup. V opačném případě ale už vynadáno dostaneme.

### $rok > 2008 was not true at pokus.pl line 9.
###     $rok was: 2001

Ukažme si ještě složitější příklad. Změníme logický výraz.

### require: $rok > 2008 or ($rok == 2008 and $mesic > 6)

Jak si s ním Smart::Comments poradí? V případě nepravdy nám vypíše hodnoty všech proměnných, které byly ve výrazu použité.

### $rok > 2008 or ($rok=2008  and $mesic > 6) was not true at comm.pl line 10.
###     $rok was: 2008
###     $mesic was: 5

Zajímavé je, že se zde samo rozpozná, které proměnné ve výrazu figurují. Kdybychom nebyli v kometáři, museli bychom s obdobným problémem postupovat daleko složitěji (stačí se podívat například na rozdíl mezi funkcemi ok a is z modulu Test::More), protože takový výraz by se vyhodnotil, aniž bychom s ním stihli cokoliv udělat.

Použijeme-li místo require (případně jeho synonym) klíčové slovo check, confirm nebo verify, bude v případě neúspěchu místo die volána funkce warn. Nezastavíme tedy program, ale jen způsobíme varování.

Animovaný progresbar

Perl obsahuje několik druhů cyklů. V případě, že právě používáme for, foreach, while nebo until, můžeme k němu vytvořit animovaný progresbar, nebo-li měnící se komentář.

Pokud neprovádíme nějaké složité výpočty nebo neprovádíme velké množství iterací, cykly většinou zaberou jen zlomky sekundy. V takovém případě bude jakékoliv animování nepostřehnutelné.

Trvá-li však výpočet dlouho, můžeme progresbar vyzkoušet. Vložme do programu nějaký cyklus a za ním uveďme komentář následujícího tvaru.

for (1..1_000_000) {       ### pracuji...      hotovo
  1+1;
}

Říká se, že milion nic zabije slona. Pravdivost tohoto tvrzení potvrzuje i předchozí kód. Na běžném počítači jeho provedení několik sekund trvá. Díky tomu progressbar snadno zaznamenáme. Uvidíme řádek, na kterém budou přibývat s postupujícími iteracemi tečky. Po pár set tisících iterací bude progressbar vypadat takto.

pracuji......                  hotovo

Komu se nelíbí tečky, může použít jiný symbol. Zde je několik možností.

### pracuji:::      hotovo
### pracuji===      hotovo
### pracuji|||      hotovo
### pracuji[]       hotovo
### pracuji{}       hotovo
### pracuji===>     hotovo
### pracuji [===>    ] hotovo

Předposlední komentář na konec progressbaru přidává symbol >. Poslední navíc umísťuje celý progressbar do závorek, kde je o něco patrnější.

Možností je ještě více. Koho zajímají, může buď experimentovat nebo se podívat do dokumentace.

Ještě zajímavější to můžeme udělat, když přidáme počet hotových procent. Změníme náš kód na následující.

for (1..1_000_000) {       ### pracuji [===>[%]   ] hotovo
  1+1;
}

Pak bude výstup zhruba v polovině iterací vypadat následovně.

pracuji [.......[63%]        ] hotovo

U cyklů, kde neznáme předem počet iterací (například while) se místo údaje o procentech zobrazí počet hotových iterací.

Časový progresbar

U cyklu for progressbar mimo jiné odhaduje, jak dlouho bude ještě trvat. Měří se zde čas a počítá se průměrná délka iterace. Vyzkoušejme následující úsek.

for (1..15) {      ### prubeh [===[%]    ]
   sleep 2;
}

Po chvíli uvidíme, kolik sekund nám zbývá do konce cyklu.

prubeh [====[35%]                 ]  (about 20 seconds remaining)

Verze pro tisk