ARCHIV

Perl (7) - Vstup poprvé

Dosud jsme psali jen programy, které s uživatelem komunikovaly jednostranně. Je čas naučit se pracovat s ovladači umožňujícími i standardní vstup.

20.4.2005 15:00 | Jiří Václavík | Články autora | přečteno 40707×

Ovladač (manipulátor) slouží ke čtení dat z nějakého zdroje (nebo-li zpřístupňuje zdroj dat) nebo naopak k zasílání dat. Před jakoukoliv komunikací tedy je třeba vytvořit ovladač. V Perlu jsou některé ovladače vytvořené již automaticky. Mezi ně patří mimo jiné STDIN (čte data ze standardního vstupu - klávesnice) a STDOUT (tiskne na standardní výstup; tento ovladač jsme nevědomky používali, když jsme tiskli pomocí print). Na ovladačích je hezké to, že zobecňují práci se zdroji dat. Ze souboru tak čteme stejným způsobem jako ze standardního vstupu.

Čtení dat z klávesnice

Čtení z již otevřeného ovladače je přímočaré. Zkusme si spustit následující program:

print "Jak se jmenuješ?\n";

$jmeno = <STDIN>;
chomp $jmeno;

print "Jsi $jmeno!\n";

Do proměnné $jmeno přiřazujeme hodnotu získanou ze standardního vstupu - STDIN. Chceme-li data získávat, musíme dát STDIN mezi < a >. Program na nás čeká, až něco napíšeme a odentrujeme. V té chvíli se do proměnné $jmeno uloží získaná hodnota a skript normálně pokračuje dál. Stojí za to připomenout, že do proměnné $jmeno se ukládá i ENTER v podobě znaku konce řádku.

Na dalším řádku voláme funkci chomp (zatím nevíme, co to funkce je, ale můžeme ji chápat podobně jako operátor), které předáváme jako parametr proměnnou $jmeno. Funkce chomp odstraňuje z konce řetězce znak konce řádku, pokud tam je. Zkusme tento řádek smazat a rozdíl bude ihned zřejmý.

Perl umožňuje tyto dva řádky zkrátit do jednoho:

chomp  ($jmeno = <STDIN>);

Poznámka: o operátoru <> se v literatuře někdy mluví jako o diamantovém operátoru nebo operátoru dvojité šipky.

Standardní výstup

Funkci print používáme, aniž bychom se starali o to, kam posílá data. Vždy se objevily na standardním výstupu. Tak se print chová implicitně. My ale můžeme ovladač změnit. Ve skutečnosti print přijímá ještě jméno ovladače výstupu. Následující zápisy jsou ekvivalentní.

print "Toto se tiskne na výstup\n";
print STDOUT "Toto se tiskne na výstup\n";

Jak vidíme, stačí před tisknutý řetězec uvést ovladač. Od řetězce je oddělen jen bílým znakem. Protože nevrací žádná data, nepíše se mezi <>.

Chceme-li tisknout text do souboru, je postup úplně stejný.

print OVLADACSOUBORU "Toto se tiskne do souboru\n";

Jak vytvořit ovladač souboru bude vysvětleno až v díle o práci se soubory, takže se tím dnes více zabývat nebudeme.

Příklad - absolutní hodnota interaktivně

V minulém dílu jsme napsali program, který počítal absolutní hodnotu čísla. Dnes ho vylepšíme tak, aby počítal absolutní hodnotu čísla, které bude přečteno ze standardního vstupu.

#!/usr/bin/env perl
use strict;

my $hodnota;
print "Zadejte hodnotu:";
chomp  ($hodnota = <STDIN>);

if ($hodnota < 0){
    $hodnota *= -1;
}

print "Absolutní hodnota zadaného čísla je $hodnota\n";

Příklad - elementární statistické charakteristiky

V další ukázce načte program ze standardního vstupu tentokrát hned tři čísla. Výsledkem bude jejich průměr, součet a největší a nejmenší ze zadaných čísel. Algoritmus není nijak složitý, takže ho není třeba podrobně popisovat.

#!/usr/bin/env perl
use strict;

my  ($a, $b, $c);                             #hodnoty, zadané ze vstupu
my  ($soucet, $prumer, $nejvetsi, $nejmensi); #proměnné, ve kterých budou výsledky
#proměnné lze definovat i takto. my přijímá jako argument seznam skalárních hodnot

print "Zadejte 1. hodnotu: "; chomp ($a = <STDIN>);
print "Zadejte 2. hodnotu: "; chomp ($b = <STDIN>);
print "Zadejte 3. hodnotu: ";
chomp ($c = <STDIN>);

$soucet = $a + $b + $c;
$prumer = $soucet / 3;

if ($a > $b and $a > $c){
    $nejvetsi = $a;
}
elsif($b > $c){
    $nejvetsi = $b;
}
else{
    $nejvetsi = $c;
}

if ($a < $b and $a < $c){
    $nejmensi = $a;
}
elsif($b < $c){
    $nejmensi = $b;
}
else{
    $nejmensi = $c;
}

print "Součet zadaných čísel je $soucet\n";
print "Průměr zadaných čísel je $prumer\n";
print "Největší ze zadaných čísel je číslo $nejvetsi\n";
print "Nejmenší ze zadaných čísel je číslo $nejmensi\n";

S pomocí cyklů, polí a funkcí by se dal předchozí příklad řešit lépe. Nám toto řešení zatím bude stačit.

Ovladač <>

Při čtení dat mezi < a > být ve skutečnosti žádný identifikátor nemusí. V tom případě bere Perl data ze souboru, který jsme přidali programu jako argument. Pokud jsme argument nepřidali, má <> stejný význam jako <STDIN>. Dodejme, že <> je ve skutečnosti pouze aliasem za <ARGV>. Následující příklad ilustruje použití.

Máme soubor kralove s tímto obsahem:

Přemysl Otakar I. 1197-1230
Václav I. 1230-1253
Přemysl Otakar II. 1253-1278

Dále máme vlastní program kralove.pl, který bude pouze přepisovat vstup na standardní výstup.

#!/usr/bin/env perl
use strict;
my $radek = <>;
print "$radek\n";

Spusťme program bez argumentu:

$ perl kralove.pl
Perl ceka na standardni vstup - neuvedli jsme parametr [ENTER]
Perl ceka na standardni vstup - neuvedli jsme parametr
$

A nyní udělejme totéž s názvem souboru jako argumentem:

$ perl kralove.pl kralove
Přemysl Otakar I. 1197-1230
$

V prvním případě program žádný argument nedostal, takže měl zápis <> stejný význam jako <STDIN> - zdrojem dat byl standardní vstup. V druhém případě byl argumentem soubor s prvními českými krály a Perl jako zdroj dat určil právě soubor kralove. Proto načítal z něj.

Ještě podotkněme, že Perl načte ze zdroje dat vždy jen jeden řádek. Proč, to bude blíže vysvětleno v odstavci o kontextech. Také je třeba zmínit, že pomocí speciální proměnné $/ lze načítat i jiné úseky, než řádky.

Počet čtení ze zdroje dat

Ve speciální proměnné $. je uložen počet přístupů k ovladači. Každý ovladač má své počítadlo. $. obsahuje hodnotu aktuálního (tedy většinou toho posledně použitého) ovladače. Chování této proměnné vysvětluje následující kód. Nejprve čteme několikkrát ze STDIN, přičemž se $. inkrementuje. Poté čteme z jiného ovladače a $. se inkrementuje opět od 0. Nakonec zavoláme ještě STDIN, proměnná $. se nenuluje, ale pokračuje tam, kde u STDIN skončila.

$a = <STDIN>; print $.;#1
$b = <STDIN>; print $.;#2
$c = <STDIN>; print $.;#3
$d = <>;      print $.;# 1
$e = <>;      print $.;# 2
$f = <STDIN>; print $.;#4

I přesto je možné získat počet čtení z jiného než posledně použitého ovladače. Funkcí seek se nastavuje aktuální ovladač.

Verze pro tisk