V tomto závěrečném dílu o knihovně Curses::UI si napíšeme textový editor. Požadavky na něj sice nebudou příliš náročné, protože půjde o obyčejný editor, který poslouží pouze k rychlé editaci textových souborů, ale měl by být schopen základních operací.

Požadavky

Náš textový editor by měl umět několik základních operací jako načíst vybraný soubor a uložit aktuální data do souboru. Tedy pokud dostaneme z příkazového řádku soubor jako parametr, měli bychom tento soubor přímo otevřít.

Realizace

Nejprve vytvoříme menu, potom widget TextEditor a pak vše ostatní.

my $cui = new Curses::UI(
    -color_support => 1,
    -language => "cs"
);

Menu se bude skládat ze dvou hlavních nabídek. V první nabídce budou tři položky: načtení souboru, uložení souboru a položka pro ukončení programu. Druhá nabídka bude obsahovat jedinou položku O aplikaci. Vytvoříme tedy odpovídající datovou strukturu.

my @menu = (
    {
         -label => "Soubor", -submenu =>
            [
                {-label => "Nacist  Ctrl-O", -value => \&open_file},
                {-label => "Ulozit  Ctrl-S", -value => \&save},
                {-label => "Konec   Ctrl-X", -value => \&exit_dialog}
            ]
    },
    {
         -label => "Napoveda", -submenu =>
            [
                {-label => "O aplikaci", -value => \&about},
            ]
    },
);

Tuto strukturu použijeme k vytvoření menu.

my $menu = $cui->add(
    "menu",
    "Menubar",
    -menu =>\@menu,
    -fg => "white",
    -bg => "blue"
);

Dále vytvoříme hlavní okno.

my $win = $cui->add(
    "win",
    "Window",
    -y => 2,
    -x => 0,
    -border => 0
);

Do něj můžeme vkládat další widgety. Vytvoříme tedy pomocí klíčového slova TextEditor textové pole, ve kterém bude uživatel moci editovat text.

my $texteditor = $win->add(
    "text",
    "TextEditor",
    -hscrollbar => 1,
    -vscrollbar => 1,
    -border=>1
);

Do tohoto okna budeme chtít hned přesunout kurzor.

$texteditor->focus();

To jsou všechny widgety, které potřebujeme. Zbývá nám už jen napsat podprogramy save a open_file.

Podprogram exit_dialog bude mít za úkol zeptat se uživatele po stisku tlačítka na ukončení programu, zda chce skutečně editor zavřít. Pokud uživatel ztvrdí rozhodnutí, program ukončíme.

sub exit_dialog {
    my $return = $cui->dialog(
        -message   => "Opravdu chcete ukoncit program?",
        -title     => "Jste si jisty?",
        -buttons   => ["yes", "no"],
    );
    exit(0) if $return;
}

V podprogramu openfile bude třeba vybrat soubor, který má být otevřen. K tomu je určena metoda loadfilebrowser. Jakmile tento soubor dostaneme, zobrazíme ho v textovém poli.

sub open_file {
    my $soubor = shift;
    $soubor = $cui->loadfilebrowser(
        -path => "/home"
    ) unless -r $soubor;

    if(-r $soubor){
        local $/ = undef;
        open DATA, $soubor;
        my $data = <DATA>;
        $texteditor->text($data);
        close DATA;
    }else{
        $cui->error("Nevybral jste soubor");
    }
    return $soubor;
}

Ještě je třeba vyřešit ukládání souborů. Tady uplatníme metodu savefilebrowser. Do vybraného souboru pak standardním způsobem zapíšeme obsah textového pole.

sub save {
    my $soubor = $cui->savefilebrowser(
        -path => "/home"
    );

    if(defined $soubor){
        local $/ = undef;
        open CIL, ">$soubor";
        print CIL $texteditor->get();
        close CIL;
    }else{
        $cui->error("Nevybral jste soubor");
    }
}

Na závěr můžeme dopsat metodu about například takto.

sub about {
    $cui->dialog("Textovy editor, verze 1.0");
}

Ještě bychom chtěli, aby se v případě volání programu s argumentem zobrazil v textovém poli přímo obsah tohoto souboru. K tomu využijeme naši funkci open_file, které předáme parametr.

open_file($ARGV[0]) if -r $ARGV[0];

Dále nastavíme pro všechny činnosti v menu klávesové zkratky.

$cui->set_binding(\&open_file, "\cO");
$cui->set_binding(\&save, "\cS");
$cui->set_binding(\&exit_dialog, "\cX");
$cui->set_binding(sub {$menu->focus();}, "\t");

Na závěr ještě můžeme upravit chování programu tak, že v dialogu na umístění souboru (tedy dialog s otázkou kam chceme ukládat nebo který soubor chceme otevřít) otevřeme jako implicitní adresář ten, ze kterého pocházel původně otevřený soubor. To můžeme udělat tak, že zavedeme nějakou globální proměnnou, ve které budeme tuto informaci uchovávat a při každém otevření souboru aktualizovat.

Závěr

Zdrojový kód programu lze stáhnout zde. Po spuštění vypadá náš editor takto.

Curses::UI textový editor